Внедрение ККМ Онлайн в сторонние конфигурации 1С

Публикация № 613979

Учет и отчетность - Кассовые операции

ККМ онлайн конфигурация Салон Рарус розница Атол 11Ф интеграция обычное приложение касса программирование торговля услуги 8.2

105
В данной статье мне бы хотелось поделиться опытом внедрения ККМ онлайн (Атол 11Ф) в одну из сторонних конфигураций 1С. Надеюсь, что она поможет сэкономить время моим коллегам, которые столкнулись с ситуацией, когда есть конфигурация, но ее поддержка разработчиком уже давно прекращена. В статье мы рассмотрим общие моменты, которые позволят "подружить" ее с онлайн кассами.

Итак, начнем с небольшого предисловия. Есть конфигурация Комильфо: Салон Красоты, поддержка которой была прекращена несколько лет назад, но в салоне, который относится к моей организации, она до сих пор используется. Как вы прекрасно знаете, государство обязало фирмы, работающие с наличными деньгами в принудительном порядке использовать онлайн кассы. И вот, руководство салона решило приобрести Атол 11Ф, но оказалось, что он не поддерживается данной конфигурацией. Тут стоит сказать несколько слов, о принципе работы с торговым оборудованием, который заложен в эту конфигурацию: как и, наверное, во всех конфигурациях от франчайзи 1С-Рарус, список доступного торгового оборудования «зашит» в специальной библиотеке, соответственно, без участия Раруса что-либо добавить в нее не представляется возможным. На просьбу добавить функционал для работы с Атол 11-Ф, была озвучена стоимость работ на 100 часов (а мы все, примерно, представляем сколько стоит 1 час работы крупного франчайзи) и руководство решило, что справится своими (т.е. моими) силами. Все, с предисловием закончили, теперь можно переходить к сути.

Я не буду останавливаться на подключении самого оборудования, так как все эти процедуры, уже были подробно описаны тут и тут. Было решено пойти по пути наименьшего сопротивления - взять готовый функционал из типовых конфигураций и перенести его. Как раз в феврале вышел свежий релиз УПП 1.3, в котором была реализована поддержка онлайн ККМ. Из УПП 1.3 нам понадобятся следующие объекты:

  1. Обработки - ТОСервер и ТОНастройка.

  2. Справочники - КассыККМ, ТорговоеОборудование и ОбработкиОбслуживанияТО.

  3. Документы - КассоваяСмена. В текущих релизах УПП, он сделан на управляемых формах, поэтому если вы не хотите переписывать его на обычные формы, то не забудьте включить использование управляемых форм в толстом клиенте в обычном режиме.

  4. Перечисления – ТООшибкиОбщие, СтатусыКассовойСмены, ТипыРасчетаДенежнымиСредствами.

  5. Регистры сведений – ТорговоеОборудование.

  6. Общие формы – ФормаНастройкиУниверсальныйДрайвер, ПараметрыФискализации.

  7. Общие модули – МенеджерОборудованияВызовСервера, МенеджерОборудованияКлиентСервер, МенеджерОборудованияКлиент, МенеджерОборудованияСервер, МенеджерОборудованияКлиентСерверПереопределяемый, МенеджерОборудованияКлиентПовтИсп, КассовыеСменыКлиент, КассовыеСменыВызовСервера.

В модуле обычного приложения:

  1. Определяем новые глобальные переменные:

Перем глПодключаемоеОборудование Экспорт;

Перем глСерверТО Экспорт;
  1. В процедуре

    ПриНачалеРаботыСистемы()

    прописываем подготовку данных для работы торгового оборудования: 

    МенеджерОборудованияКлиент.ПриНачалеРаботыСистемы()

  2. Прописываем функцию для взаимодействия с ТО:

Функция ПолучитьСерверТО() Экспорт

	Если глСерверТО = Неопределено Тогда
		глСерверТО = Обработки.ТОСервер.Создать();
	КонецЕсли;

	Возврат глСерверТО;

КонецФункции // ПолучитьСерверТО()

Далее, идем в документ, который отвечает за печать чека, в моем случае это был документ «Чек». 

При открытии документа подключаем работу с ТО:

ПолучитьСерверТО().ПодключитьКлиента(ЭтаФорма);

При закрытии – отключаем:

ПолучитьСерверТО().ОтключитьКлиента(ЭтаФорма);

Так же нам необходимо внешнее событие :

Процедура ВнешнееСобытие(Источник, Событие, Данные)

	Если Не ВводДоступен() Тогда
		Возврат;
	КонецЕсли;

	ПолучитьСерверТО().ОбработатьВнешнееСобытие(Источник, Событие, Данные, ЭтаФорма);

КонецПроцедуры // ВнешнееСобытие()

И функция для поддержки ТО:

Функция ПоддерживаетсяВидТО(Вид) Экспорт

	Результат = Ложь;

	Если Вид = Перечисления.ВидыТорговогоОборудования.СканерШтрихКода
	 Или Вид = Перечисления.ВидыТорговогоОборудования.СчитывательМагнитныхКарт
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ДисплейПокупателя
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ЭлектронныеВесы
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ФискальныйРегистратор
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ТерминалСбораДанных
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ЭквайринговаяСистема 
	 Или Вид = Перечисления.ВидыТорговогоОборудования.ККТ Тогда
		Результат = Истина;
	КонецЕсли;

	Возврат Результат;

КонецФункции // ПоддерживаетсяВидТО()

Теперь меняем процедуру, которая отвечает за печать самого чека. 

Процедура ОсновныеДействияФормыПробитьЧекНовый(Кнопка)
	Перем Ответ;
	Перем Отказ;

	Если ПровестиИРаспечататьЧек(Ответ, Отказ, Истина) Тогда 
		флПробит								=	Истина;
		Попытка
			ЭтотОбъект.Записать();
		Исключение
		КонецПопытки;
		ПраваДоступа.НеДоступностьРедактированияЭлементовНаФорме(ЭлементыФормы);
		ЭлементыФормы.ДействияФормы.Доступность	=	Ложь;
		ЭлементыФормы.ОсновныеДействияФормы.Кнопки.ПробитьЧекНовый.Доступность = Ложь;
	Иначе
		Предупреждение(?(Отказ, "Возможны расхождения ИБ и ленты ФР! ", "") + Ответ);
	КонецЕсли;
КонецПроцедуры

И добавляем в модуль документа две функции: 

Функция ПровестиИРаспечататьЧек(Ответ, Отказ, РучнойРежимПечати = Ложь) Экспорт

	Результат = Истина;
	Ответ     = "";

	Попытка
		Записать();
	Исключение
		Ответ     = "Ошибка при попытке проведения документа!";
		Отказ     = Истина;
		Результат = Ложь;
		Возврат Результат;
	КонецПопытки;

	Если ФлПробит Тогда
		Возврат Результат;
	КонецЕсли;

	Если КассаККМ.ФормироватьНефискальныеЧеки
	   И КассаККМ.РучнойРежимФормирования
	   И Не РучнойРежимПечати Тогда
		Возврат Результат;
	КонецЕсли;

	МассивФР      = ПолучитьСерверТО().ПолучитьСписокУстройств(
	                    Перечисления.ВидыТорговогоОборудования.ФискальныйРегистратор,
	                    КассаККМ);
	МассивККТ     = ПолучитьСерверТО().ПолучитьСписокУстройств(
	                    Перечисления.ВидыТорговогоОборудования.ККТ,
	                    КассаККМ);
	МассивФУ = Новый Массив();
	ОбщегоНазначенияКлиентСервер.ДополнитьМассив(МассивФУ, МассивФР);
	ОбщегоНазначенияКлиентСервер.ДополнитьМассив(МассивФУ, МассивККТ);

	ФУ            = Неопределено;
	СписокФУ      = Новый СписокЗначений();
	Вид           = Неопределено;
	Представление = Неопределено;

	Для каждого ФУ Из МассивФУ Цикл
		ПолучитьСерверТО().ПолучитьПредставлениеУстройства(ФУ, Вид, Представление);
		СписокФУ.Добавить(ФУ, Представление);
	КонецЦикла;

	КоличествоФУ = СписокФУ.Количество();
	Если      КоличествоФУ = 0 Тогда
		Ответ     = "";
		Отказ     = Истина;
		Результат = Истина;
		Возврат Результат;
	ИначеЕсли КоличествоФУ = 1 Тогда
		ФУ = СписокФУ[0].Значение;
	Иначе
		ФУ = СписокФУ.ВыбратьЭлемент("Необходимо выбрать фискальное устройство");
		Если ФУ = Неопределено Тогда
			Ответ     = "Операция отменена пользователем.";
			Отказ     = Истина;
			Результат = Ложь;
			Возврат Результат;
		Иначе
			ФУ = ФУ.Значение;
		КонецЕсли;
	КонецЕсли;

	ОшибкаТО = Перечисления.ТООшибкиОбщие.ПустаяСсылка();
	
    //У меня, организация не занимается продажей алкоголя, поэтому чтобы не переносить лишнее, было решено сразу установить "Ложь".
    //Если у вас есть торговля алкоголем, тогда надо дополнительно перенести подсистему ИнтеграцияЕГАИС и смотреть, как реализовано 
    //взаимодействие с ЕГАИС в документе ЧекККМ, функция ПровестиИРаспечататьЧек.
    
    ИспользуетсяРегистрацияВЕГАИС = Ложь;
	
	ВидФУ = ПолучитьСерверТО().ПолучитьВид(ФУ);
	Если ВидФУ = Перечисления.ВидыТорговогоОборудования.ККТ Тогда
		ОписаниеПКС = КассовыеСменыВызовСервера.ОписаниеПоследнейКассовойСмены(ФУ);
		Если ОписаниеПКС = Неопределено ИЛИ ОписаниеПКС.Статус = Перечисления.СтатусыКассовойСмены.Закрыта Тогда
			Ответ = "Кассовая смена не открыта";
			Отказ = Истина;
			Результат = Ложь;
			Возврат Результат;
		КонецЕсли;
		Результат = ФискализироватьЧек(ФУ, Ответ, Отказ);
		Если Результат Тогда
			ЧекПробитНаККМ = Истина;
			Попытка
				Записать(РежимЗаписиДокумента.Запись);
			Исключение
				Ответ     = "Не удалось записать документ с установленными параметрами пробитого чека.";
				Отказ     = Истина;
				Результат = Ложь;
			КонецПопытки;
		КонецЕсли;
		Возврат Результат;
	КонецЕсли;
	
	ДопДанные = Новый Структура;
	НомерСменыККМ = Число(СвязныйЧек.НомерСмены); //Номер смены (известен для копии чека)
	НомерЧекаККМ = Число(СвязныйЧек.НомерЧека);
	
	ТаблицаТоваров	=	ОплатаЧеком.Выгрузить();
	
	ОшибкаТО = ПолучитьСерверТО().ПечатьЧека(ФУ, "", НомерЧекаККМ, НомерСменыККМ,ТаблицаТоваров, Ссылка.СуммаДокумента,0,Ложь, ДопДанные);
	
	Если НЕ ЗначениеЗаполнено(ОшибкаТО) Тогда
		ЧекПробитНаККМ = Истина;
		Попытка
			Записать(РежимЗаписиДокумента.Запись);
		Исключение
			Ответ     = "Не удалось записать документ с установленными параметрами пробитого чека.";
			Отказ     = Истина;
			Результат = Ложь;
		КонецПопытки;
	Иначе
		Ответ     = ПолучитьСерверТО().ПолучитьТекстОшибкиФРТО(ОшибкаТО);
		Отказ     = Истина;
		Результат = Ложь;
	КонецЕсли;

	Возврат Результат;

КонецФункции // ПровестиИРаспечататьЧек()
Функция ФискализироватьЧек(ФУ, Ответ, Отказ)
	
	Ответ = "";
	Отказ = Ложь;
	Результат = Истина;
	
	ПараметрыЧека = Неопределено;
	ПодготовитьДанныеДляФискализацииЧека(Ссылка, ПараметрыЧека);
	
	ОбъектДрайвера = Неопределено;
	ОбработкаОбслуживания = Неопределено;
	ПолучитьСерверТО().ПолучитьОбъектДрайвера(ФУ, ОбработкаОбслуживания, ОбъектДрайвера);
	
	ОшибкаТО = ОбработкаОбслуживания.ФискализироватьЧек(ОбъектДрайвера, ПараметрыЧека);
	Если ЗначениеЗаполнено(ОшибкаТО) Тогда
		Ответ = ОбъектДрайвера.ОписаниеОшибки;
		Отказ = Истина;
		Результат = Ложь;
	КонецЕсли;
	
	Возврат Результат;

КонецФункции

И одну процедуру:

Процедура ПодготовитьДанныеДляФискализацииЧека(ЧекККМ, ОбщиеПараметры)
	
	ОбщиеПараметры = МенеджерОборудованияКлиентСервер.ПараметрыОперацииФискализацииЧека();

	ОрганизацияЧека = ЧекККМ.КассаККМ.Владелец;	
	// Шапка
	ОбщиеПараметры.ДокументОснование = ЧекККМ;
	Если ЧекККМ.ХозОперация = Перечисления.РежимЧека.Чек Тогда 
		ОбщиеПараметры.ТипРасчета =	ПредопределенноеЗначение("Перечисление.ТипыРасчетаДенежнымиСредствами.ПриходДенежныхСредств");
	ИначеЕсли ЧекККМ.ХозОперация = Перечисления.РежимЧека.ЧекНаВозврат Тогда
		ОбщиеПараметры.ТипРасчета = ПредопределенноеЗначение("Перечисление.ТипыРасчетаДенежнымиСредствами.ВозвратДенежныхСредств")
	Иначе 
		Сообщить("Копии чека, больше не используются!");
		Возврат;
	КонецЕсли;
	
	ОбщиеПараметры.Кассир = ЧекККМ.Ответственный.Наименование;
	ОбщиеПараметры.Электронно = Ложь; // Чек будет напечатан
	ОбщиеПараметры.Отправляет1СSMS = Ложь;
	ОбщиеПараметры.Отправляет1СEmail = Ложь;
	ОбщиеПараметры.ОрганизацияНазвание = ОрганизацияЧека.ПолноеНаименование;
	ОбщиеПараметры.ОрганизацияИНН = ОрганизацияЧека.ИНН;
	ОбщиеПараметры.ОрганизацияКПП = ОрганизацияЧека.КПП;
    ПорядокНалогообложения = Неопределено;
	ДопДанные.Свойство("ПорядокНалогообложения", ПорядокНалогообложения);
	ОбщиеПараметры.КодСистемыНалогообложения = МенеджерОборудованияКлиентСервер.КодСистемыНалогообложения
		(ОрганизацияЧека, ЧекККМ.Дата, ПорядокНалогообложения);	
	// Оплаты	
	ОплатыЧека = ЧекККМ.ПолучитьОбъект().ИтогиОплатПоТипам();
	СуммаТипаОплаты = ОплатыЧека.Получить(Перечисления.ВидыОплаты.Наличные);
	Если СуммаТипаОплаты <> 0 И СуммаТипаОплаты <> Неопределено Тогда
		СтрокаОплаты = Новый Структура();
		СтрокаОплаты.Вставить("ТипОплаты", 0);
		СтрокаОплаты.Вставить("Наименование", "Наличная оплата");
		СтрокаОплаты.Вставить("Сумма", СуммаТипаОплаты);
		ОбщиеПараметры.ТаблицаОплат.Добавить(СтрокаОплаты);
	КонецЕсли;
	СуммаТипаОплаты = ОплатыЧека.Получить(Перечисления.ВидыОплаты.Безналичные);
	Если СуммаТипаОплаты <> 0 И СуммаТипаОплаты <> Неопределено Тогда
		СтрокаОплаты = Новый Структура();
		СтрокаОплаты.Вставить("ТипОплаты", 1);
		СтрокаОплаты.Вставить("Наименование", "Платежная карта");
		СтрокаОплаты.Вставить("Сумма", СуммаТипаОплаты);
		ОбщиеПараметры.ТаблицаОплат.Добавить(СтрокаОплаты);
	КонецЕсли;
	// Товарные позиции
	Для Каждого СтрокаТовара Из ЧекККМ.ОплатаЧеком Цикл
		СтрокаЧека = МенеджерОборудованияКлиентСервер.ПараметрыФискальнойСтрокиЧека();
		
		// Обязательные поля
		СтрокаЧека.Наименование = СтрокаТовара.Номенклатура.Наименование; // Наименовнование предмета расчета
		СтрокаЧека.Количество = СтрокаТовара.Количество; // Количество предмета расчета 
		СтрокаЧека.Цена = СтрокаТовара.Цена; // Цена без учета скидок и наценок
		СтрокаЧека.Сумма = СтрокаТовара.Сумма; // Cтоимость предмета расчета с учетом скидок и наценок
		СтрокаЧека.СтавкаНДС = МенеджерОборудованияКлиентСервер.ПолучитьСтавкуНДСДляФискализацииЧека
			(СтрокаТовара.Номенклатура.СтавкаНДС, ПорядокНалогообложения); // Cтавка НДС в %
		//СтрокаЧека.Штрихкод = СокрЛП(СтрокаТовара.ШтрихКод); // Штрихкод
		// Дополнительные реквизиты начиная с ФФД 1.1
		СтрокаЧека.КодПризнакаСпособаРасчета = 4;  // Код признака способа расчета (Таблица 25 документа ФФД)
		СтрокаЧека.КодПризнакаПредметаРасчета = ?(СтрокаТовара.Номенклатура.Услуга,4,1); // Код признака предмета расчета   (Таблица 25 документа ФФД)

		ОбщиеПараметры.ПозицииЧека.Добавить(СтрокаЧека);
	КонецЦикла;

КонецПроцедуры

Ну и последнее, что нам осталось, в общем модуле КассовыеСменыВызовСервера, в процедуре

ПослеВыполненияКомандыФискальнымУстройством(ПараметрыКоманды) Экспорт

В части, где выполняются действия с обработанными чеками после закрытия смены, прописать свою обработку для закрытия смены.

Если (ПараметрыКоманды.ВыполняемаяКоманда = "CloseShift" ИЛИ ПараметрыКоманды.ВыполняемаяКоманда = "ЗакрытьСмену") 
		И ПараметрыКоманды.ОбрабатыватьЧекиККМ = Истина Тогда
		
		//ЗакрытиеКС = Обработки.ЗакрытиеКассовойСмены.Создать();
		//ЗакрытиеКС.Дата = КассоваяСменаОбъект.Дата;
		//ЗакрытиеКС.КассаККМ = КассоваяСменаОбъект.КассаККМ;
		//ЗакрытиеКС.ОбработкаЧековККМ(Справочники.Склады.ПустаяСсылка());
		ЗакрытиеКС = Обработки.ЗакрытиеСмены.Создать();
		ЗакрытиеКС.ОбработкаЧековККМ(КассоваяСменаОбъект.Дата, КассоваяСменаОбъект.КассаККМ.Владелец);
КонецЕсли;

Ах да, не знаю исправили эту ошибку или нет, но в феврале, при закрытии смены, всегда выдавало ошибку:

Ошибка вызова метода <ОбъектДрайвера.ЗакрытьСмену>. 
Ошибка при вызове метода контекста (XMLЗначение): Несоответствие типов (параметр номер '2')

Все дело было в функции

ПолучитьПараметрыСостоянияСменыИзXMLПакета(Данные, НомерСмены)

  в общем модуле МенеджерОборудованияВызовСервера. Необходимо заменить на следующий код:

Функция ПолучитьПараметрыСостоянияСменыИзXMLПакета(Данные, НомерСмены) Экспорт
    
    ЧтениеXML = Новый ЧтениеXML; 
    ЧтениеXML.УстановитьСтроку(Данные);
    ЧтениеXML.ПерейтиКСодержимому();
    
    Параметры = МенеджерОборудованияКлиентСервер.ПараметрыНормализуемыхФискальныхДанных();
    Параметры.НомерСменыККТ = НомерСмены;
    
    Если ЧтениеXML.Имя = "StatusParameters" И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда
        Если ЧтениеXML.Прочитать() И ЧтениеXML.Имя = "Parameters" И ЧтениеXML.ТипУзла = ТипУзлаXML.НачалоЭлемента Тогда  
            Параметры.КоличествоНепереданныхФД    = Число(ЧтениеXML.ЗначениеАтрибута("BacklogDocumentsCounter"));
            Параметры.НомерПервогоНепереданногоФД = ЧтениеXML.ЗначениеАтрибута("BacklogDocumentFirstNumber");
            BacklogDocumentFirstDateTime = ЧтениеXML.ЗначениеАтрибута("BacklogDocumentFirstDateTime");
            Если ЗначениеЗаполнено(BacklogDocumentFirstDateTime) Тогда
                Параметры.ДатаПервогоНепереданногоФД  = XMLЗначение(Тип("Дата"), BacklogDocumentFirstDateTime);
            Иначе
                Параметры.ДатаПервогоНепереданногоФД = Дата(1,1,1);
            КонецЕсли;
        КонецЕсли;
    КонецЕсли;
    
    Возврат Параметры;
    
КонецФункции

Спасибо Алексею Васильеву.

Вот и все. Теперь через новую Обработку подключения оборудования загружаем обработки обслуживания и добавляем наш Атол 11Ф.

Время затраченное на обдумываение и реализацию, составило 2 рабочих дня и еще пару дней на отладку. Естественно, что в статье я не привожу полный код из перенесенных модулей и документов, но сразу скажу - в перенесенном "как есть" виде, он будет выдавать ошибки. Некоторые процедуры надо будет убрать, некоторые немного переделать, но все это быстро поддается отладке. Надеюсь, что данная статья будет вам полезна, если вы столкнетесь с похожей ситуацией. В случае возникновения каких-либо вопросов, можно задать их через ЛС.  

P.S. На двух последних скриншотах полностью показаны все новые объекты, которые я переносил из УПП. Так как я решил сделать задел на будущее и полностью перейти на типовую работу с ТО, то объектов в подсистеме несколько больше, чем указано в статье.

P.P.S. Компания 1С, очень трепетно относится к лицензионному соглашению, а так как при доработке конфигурации используется код из УПП, то будет не лишним напомнить, что у вас должна быть приобретена лицензия на этот программный продукт.  

105

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. karpik666 2716 22.04.17 07:04 Сейчас в теме
Судя по описанию, у вас точно данный код взлетел? в конфигурации автосалон от рарус нет большинства реквизитов, не описали, как будет вводиться email и номер телефона. Как я помню нет реквизита ответственный, а вместо него автор. У кассы ккм нет реквизитов формировать не фискальные чеки. Также у вас применяются документа приходный кассовый ордер и расходный?
lord_soth; +1 Ответить
2. lord_soth 293 22.04.17 08:25 Сейчас в теме
(1) Не скажу насчёт Автосалона, но для Комильфо Салон Красоты точно работает. С февраля все чеки печатаются только через 11ф, на сайте ОФД видны. Отправка чека по смс и на почту, пока не была реализована в текущих релизах, в УПП этих возможностей точно нет. Понятно, что код для разных конфигураций не будет совпадать с точностью до реквизита. Статья, по большей части, носит рекомендательный характер - откуда и какие именно части взять, которые отвечают за работу с онлайн кассами и доделать их под свои конфигурации.
3. karpik666 2716 22.04.17 08:29 Сейчас в теме
(2) ааа, я думал автосалон тогда наверное да. Не думал вывести на форму реквизиты "Электронный чек" и "Вводить email или номер клиента", для настройки отправки чеков?
6. lord_soth 293 23.04.17 15:53 Сейчас в теме
(3) Конечно думал, но пока такой срочной необходимости в электронных версиях чеков нет.
4. ivanov660 1627 22.04.17 20:35 Сейчас в теме
Обожаю замечательный стиль в коде:
1.
Справочники.Организации.НайтиПоКоду("0000000001");

и вот это тоже, замечательно
2.
СтрокаЧека.СтавкаНДС = 0; // Cтавка НДС в %
		Если СтрокаЧека.СтавкаНДС = Неопределено Тогда
			СтрокаЧека.СтавкаНДС = 0;
		КонецЕсли;

3.
ОбщиеПараметры.Кассир = ЧекККМ.Ответственный.Наименование;

4. Надо было бы отметить, что код для обычного приложения.
5. spectre1978 50 23.04.17 09:10 Сейчас в теме
(4) с учётом того что выложено бесплатно и даже не за стартмани - и за это огромное спасибо. Автору от меня плюс.
Aston1924; Sera; karpik666; alek-sand-er; orfos; rybolovlev_ms; Dmitri93; manlak; shard; PhoenixAOD; Mantis; AlexeyFreeLife; roman77; madonov; lord_soth; +15 1 Ответить
7. ivanov660 1627 23.04.17 20:25 Сейчас в теме
(5) Не согласен, можно было потратить еще минут 20-30 и привести пример в надлежащее состояние.
Из вашего высказывания неявно следует - бесплатно значит и "так сойдет". Использование подобного подхода ведет в никуда.
8. spectre1978 50 23.04.17 22:40 Сейчас в теме
(7) это с какой стороны посмотреть. Автор лично вам ничем не обязан, и мог бы не тратить на подготовку публикации ни пяти минут, ни одной. Тем не менее он это сделал и вы можете брать и пользоваться его кодом как полностью, так и заменяя то, что вас не устраивает, при этом вы не платите ни копейки. В целях понимания логики работы он достаточно полезный, на универсальное и рабочее во всех случаях решение не претендует - это по сути полуфабрикат. Поэтому извините, но неконструктивно. Как по мне - так лучше с "найтипокоду", чем вообще ничего и каждый будет ковыряться самостоятельно.
manlak; shard; Tolpinski; Mantis; AlexeyFreeLife; dkonakov; roman77; lord_soth; fancy; madonov; +10 Ответить
10. ivanov660 1627 24.04.17 11:40 Сейчас в теме
(8) Я автора ни о чем и не прошу, это вопрос его личной кармы.
9. lord_soth 293 24.04.17 09:15 Сейчас в теме
(4) Со вторым замечанием согласен, в первым нет, но поправил, третье - это код самих разработчиков 1С, четвертое - вы невнимательно читали, там где перечислены объекты для переноса, сказано про обычное приложение.
11. ivanov660 1627 24.04.17 11:47 Сейчас в теме
(9) Я думаю, все же не стоит равняться на некачественный код разработчиков 1С.
Про то что код для обычного приложения написано косвенно.
"...если вы не хотите переписывать его на обычные формы, то не забудьте включить использование управляемых форм в толстом клиенте в обычном режиме."
12. premierex 26.04.17 08:44 Сейчас в теме
(0)
...взять готовый функционал из типовых конфигураций и перенести его. Как раз в феврале вышел свежий релиз УПП

Какое-то время назад я, разрабатывая индивидуальную конфигурацию для одной из организаций, решил использовать некоторые механизмы (давно отлаженные и отработанные) из типовой конфигурации от 1С. Но, поскольку, в организации шла борьба за чистоту программного обеспечения, решил проконсультироваться в компании 1С: будет ли нарушением лицензионного соглашения использование в собственной (индивидуальной) конфигурации объектов и (или) фрагментов кода из типовой конфигурации 1С? Ответ был однозначным: использование объектов, а также фрагментов программного кода типовых конфигурации без приобретения коробочного продукта с конфигурацией, фрагменты которой были использованы, является нарушением лицензионного соглашения с компанией 1С.
Таким образом, для того, чтобы использовать вышеприведенную методику подключения ККТ онлайн и сохранить чистоту программного обеспечения в плане лицензирования, потребуется как минимум приобретение коробочного продукта 1С:УПП, рекомендованная цена которого на дату публикации составляет 223 000 руб. Стоит призадуматься...
lord_soth; +1 Ответить
13. lord_soth 293 26.04.17 09:22 Сейчас в теме
(12) Да, я тоже думал на этот счет, но так как у меня есть лицензионная УПП + ИТС, то проблем не возникло. На всякий случай, добавил этот момент в статью. Спасибо.
14. spectre1978 50 26.04.17 14:06 Сейчас в теме
(12) с одной стороны как бы да. С другой стороны ведь очевидно, что при условии доступности исходного кода никто не мешает переписать его до полной неузнаваемости, использовав вместо оригинальных конструкций синонимические, и другие имена. После такой модификации будет крайне сложно доказать что это один и тот же код.
16. premierex 26.04.17 16:31 Сейчас в теме
(14) (15) И тем не менее... Как бы абсурдно это ни звучало...
В соответствии с законом тиражирование и распространение прикладного решения, созданного с использованием фрагментов кода типовой конфигурации "1С", возможно только по разрешению правообладателя. Тиражные решения, созданные с использованием кода типовой конфигурации, могут поставляться пользователям, правомерно владеющим основной поставкой "1С:Предприятия 8", на основе которой создано данное тиражное решение.

Ответы на типовые вопросы по лицензированию "1С:Предприятия 8".
17. IVC_goal 113 26.04.17 16:52 Сейчас в теме
(16) Я же не против этого. Я только обращаю, Ваше, внимание на то, что строка кода "Пока Выборка.Следующий() Цикл", является фрагментом используемым в типовых конфигурациях 1с. Со всеми вытекающими последствиями.Вывод сделайте сами
18. premierex 27.04.17 08:14 Сейчас в теме
(17) Синтаксические конструкции языка 1С под ограничения лицензионного соглашения не попадают, как и не охраняются законом о защите авторских прав, так как они являются неотъемлемой частью встроенного языка. Поэтому использование вышеприведенной конструкции никаких последствий не повлечет и повлечь не может.
Речь идет о фрагментах кода, выполняющих функционал, специфичный для определнной типовой конфигурации 1С. Естественно, написать такой же функционал самостоятельно - можно, а просто взять и скопировать из типовой конфигурации - нет, так как см. (16).
19. IVC_goal 113 27.04.17 09:08 Сейчас в теме
(18) Отлично, что не попадает мы знаем, но более интересно (и не только мне) будет прочитать, какие существуют формализованные критерии оценки программного кода, который попадает под лицензионное соглашение? Только не общие слова.
20. premierex 27.04.17 10:48 Сейчас в теме
(19) Поизучайте материал по ссылке из (16). "Общие слова" именно оттуда.
27. Rustig 1194 28.06.18 01:00 Сейчас в теме
(18) не получится "просто взять и скопировать" - не взлетит код
все алгоритмы приходится адаптировать и модифицировать под свою конфигурацию.
короче говоря, не стоит заморачиваться.
15. IVC_goal 113 26.04.17 16:04 Сейчас в теме
(12) Это все равно, что создать лицензию на алфавит. Абсурдность такой позиции ("использование ... фрагментов программного кода") очевидна и не доказуема с юридической точки зрения.Автору большой и жирный +
21. KrivosheevEV 02.05.17 17:46 Сейчас в теме
В документации Атолла есть подробное описание интерфейса драйвера. Куча примеров для многих языков. Можно формировать чеки даже из Excel. К чему этот ажиотаж по 54ФЗ?
22. spectre1978 50 09.05.17 12:10 Сейчас в теме
(21) в основном стоит задача подключиться к кассе стандартными средствами без своих велосипедов или с минимальными, используя уже имеющиеся наработки для обычных касс.
24. coolseo 53 06.07.17 03:34 Сейчас в теме
(21) Здравствуйте, примеры из эксель находятся тут?
C:\Program Files (x86)\ATOL\Drivers8\Samples\FprnM\Excel2000\ExcelEx.xls
Они точно под 54фз или только под древние драйвера?
25. KrivosheevEV 07.07.17 11:39 Сейчас в теме
(24) Примеры описывают взаимодействие с интерфейсом драйвера. И к 54ФЗ имеют косвенное отношение.
Из опыта: на кассе успешно регистрируются операции, декларируемые в примерах; данные успешно уходят ОФД.
23. rozer 259 05.07.17 12:12 Сейчас в теме
с выходом ут10.3.43 с поддержкой ффд 1.05 и прочих статья несколько устарела (
26. Marika2017 18.07.17 16:17 Сейчас в теме
А можете напрямую обратиться к разработчику программы Комильфо - ООО "УмКо", тел 8(8422) 27 27 80, у них есть готовый модуль.
28. user1261992 04.08.19 11:17 Сейчас в теме
Добрый день. Подскажите будет ли работать Ваша программа FR_Atol_Shtrih.exe с ККМ АТОЛ-92 F
Оставьте свое сообщение

См. также

Подключение АТОЛ 91/92Ф к 1С:Касса 5

Статья Системный администратор Нет файла v8 1cv8.cf Россия Кассовые операции Бесплатно (free) ККМ

Т.к. я не нашел данной информации в гугле (возможно, плохо искал), решил, что нужно оставить эту статью здесь, может, поможет кому.

10.09.2019    1065    rule_2    2       

Решение проблем с сетевым ключом защиты для Штрих-М: Торговое предприятие 5 4

Статья Системный администратор Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Windows Розничная торговля Бесплатно (free) Администрирование данных 1С

Штрих-М: Торговое предприятие 5 имеет свой ключ защиты, который проверяет сразу после запуска базы. Если вы увидели сообщение "ключ не найден", материал в этой статье может помочь решить вашу проблему.

21.08.2019    1010    Van2507    0       

Вывод отчетов из Штрих-М Торговое предприятие 5 на кассовое ПО Кассир 5 через веб-сервис 3

Статья Системный администратор Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Windows Розничная торговля Бесплатно (free) WEB

Универсальный механизм вывода отчетов товароучетной системы Штрих-М Торговое предприятие в кассовое ПО Кассир 5 посредством веб-сервиса.

14.08.2019    913    Van2507    1       

Чеки ККМ для расчетов с ИП по безналу. Новые обязательные реквизиты в чеке 32

Статья Программист Нет файла v8 v8::ОУ УТ11 УУ Windows Оптовая торговля Бесплатно (free) Практика программирования ККМ Разработка

Новые требования законодательства по пробитию чеков ККМ при расчетах с индивидуальными предпринимателями по безналу. Нюансы подключения интеграционной компоненты ДТО 10.5.0 на примере кассы ККТ АТОЛ 11Ф и конфигурации 1С УТ 11.4. Необходимые доработки типовой конфигурации УТ 11.4 для вывода на печать новых обязательных реквизитов: покупатель, ИНН, ГТД, страна происхождения.

22.07.2019    5496    ids79    16       

Маркировка табака. Формирование тега 1162 "код товара" для передачи в ККТ и ОФД 5

Статья Программист Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия Розничная торговля Бесплатно (free) Практика программирования Разработка

С 01.07.2019 стартует новый этап маркировки сигарет. Теперь в кассе обязательно надо будет считывать марку с пачек табака, если она там есть. Считывать и передавать в ОФД через тег 1162 в онлайн-кассе. А как сформировать данные этого тега? Не все так просто...

27.06.2019    2427    kirlog    26       

Система питания в офисе: как совместить вендинговые автоматы, 1С, облачную кассу и веб-технологии 6

Статья Руководитель проекта Нет файла v8 1cv8.cf Розничная и сетевая торговля (FMCG) Россия УУ Розничная торговля Бесплатно (free) Интеграция

В начале 2019 года тенденция развития автоматов питания в России привела к появлению проекта нового формата питания на работе — МикроМаркета “Го!Поедим”. Потребовалось создать новый формат зоны питания сотрудников: интегрировать в офисные кухни полноценные МикроМаркеты с бесконтактной оплатой, кофе-машинами, лаунж-зоной. Если правильно совместить вендинговые автоматы, облачную кассу, 1С и веб-технологии, то в результате будут не только сытые сотрудники, но и корректная работа всей системы офисного питания.

22.06.2019    1766    antonovintervolga    6       

1С и компьютерное зрение: новый подход к контролю за ассортиментом магазина 23

Статья Бизнес-аналитик Нет файла v8 1С:Франчайзи, автоматизация бизнеса УУ Розничная торговля Бесплатно (free) Внешние источники данных

Машинное зрение в магазинах и 1С. Как поднять эффективность торгового предприятия (магазин. кафе, шоурум и т.д.) с совершенно неожиданной стороны? Как получить реальные демографические данные покупателей и, самое главное, как это использовать в повседневной работе магазина? Как можно расширить привычные ABC и XYZ анализ, добавив в них пласт данных о трафике и демографии покупателей? Что необходимо для 1С, чтобы использовать данные видеоанализа людского трафика?

20.06.2019    3483    osipov_cvizi    16       

Сжатие данных в мобильном приложении 1С:Предприятие 42

Статья Программист Нет файла v8 v8::Mobile 1cv8.cf УУ Розничная торговля Бесплатно (free) Мобильная разработка

Эту небольшую статью я планировал опубликовать у себя на сайте, чтобы такие любители мобильного приложения от 1С:Предприятие, как я, могли использовать её без дополнительно потраченных двух дней на поиски вариантов написания алгоритма. Во-первых, хотел сказать, что я небольшой разработчик, который начинал делать свои первые шаги ещё на заре правления "Семерки". Новая платформа версии 8 была как глоток свежего воздуха - бодрящий и легко воспринимаемый организмом. Я был очень удивлен, да что сказать, до сих пор удивляюсь как элементарные вещи можно делать на 1С, и как это стремно делается на других языках программирования. Во-вторых, обилие разнообразных интерпретаций платформы позволяет развернуться на все 360 градусов, захватив своими проектами, наверное, любые ветки бизнеса. Так вот, о небольшом нюансе работы с новой мобильной платформой я и хотел рассказать... Сам додумался, так сказать.

27.05.2019    7564    yarsort    27       

Рассрочка в Рознице 2.2 1

Статья Программист Нет файла v8 Розница УУ Розничная торговля Бесплатно (free) Практика программирования Разработка

Добавляем Рассрочку в документ "Отчет о розничных продажах" в конфигурации "Розница для Беларуси, редакция 2.2."

15.04.2019    1316    borlog    0       

Весы Штрих-СЛИМ, Штрих-ПРИНТ и 1С: Розница 2.2.11.ХХ 8

Статья Системный администратор Нет файла v8 Розница Розничная и сетевая торговля (FMCG) Россия Windows Розничная торговля Бесплатно (free) Весы

Как установить драйвер весов по протоколу POS2 или драйвер ШТРИХ-М:Весы с печатью этикеток ШТРИХ-ПРИНТ на Windows 7 и выше.

29.01.2019    4581    Newdjeen    6       

Возврат товаров, проданных в прошлых кассовых сменах, через Чек ККМ на возврат 0

Статья Программист Нет файла v8 УТ11 Россия Кассовые операции Бесплатно (free) Практика программирования

В Управлении торговлей 11.4 разработчики зачем-то сделали возможность делать "Чек ККМ на возврат" для Чеков ККМ, сделанных прошлыми датами. Причем чек на возврат создается и печатается, но потом при закрытии смены формируется "Отчет о розничных продажах", который ставит отрицательное количество по возвращенным позициям. Это в свою очередь ведет к тому, что с включенным контролем остатков этот "Отчет о розничных продажах" не проводится.

19.01.2019    4087    nagimo    22       

Работа с кассой Atol через веб-сервер ДТО-10 54

Статья Программист Нет файла v8 Россия Кассовые операции НДС Бесплатно (free) Внешние источники данных ККМ Фискальный регистратор

Поддержка многопользовательской печати на одном устройстве ККТ. Поддержка изменений в законодательстве (Переход на ФФД 1.05 и НДС 20%).

31.12.2018    16572    medangel    36       

Редактирование цены в РМК. 1С: УТ 11 7

Статья Программист Нет файла v8 УТ11 Россия Розничная торговля Бесплатно (free) Практика программирования

В типовой конфигурации УТ 11 нет возможности в режиме РМК изменить цену на товар, хотя такая необходимость появляется довольно часто. Внеся небольшие изменения в конфигурацию, можно добиться нужной функциональности. Использовался релиз 1С УТ 11.4.5.135 на платформе 1С:Предприятие 8.3 (8.3.13.1513).

26.12.2018    3252    Stæg    8       

Внесение денежных средств в ККМ прямо из РМК 3

Статья Программист Нет файла v8 Розница Розничная и сетевая торговля (FMCG) Россия Кассовые операции Бесплатно (free) Практика программирования

В типовом механизме внесения ДС в кассу ККМ требуется наличие расходного кассового ордера, но основании которого будет создан документ "Внесение денежных средств в кассу ККМ". Если его нет (и соответственно остатков по РН "ДенежныеСредстваКПоступлениюНаличные"), то выводится сообщение "Нет документов по внесению ДС" (в противном случае открывается список РКО, на основании которых требуется создать внесение ДС). Данная доработка позволяет автоматически создать РКО (с видом операции "Выдача денежных средств в кассу ККМ") вместо выдачи сообщения об отказе и звонку бухгалтеру/администратору.

12.10.2018    2609    triviumfan    0       

Прикладной пример переработки стандартной формы РМК - Розница 74

Статья Программист Нет файла v8 Розница УУ Кассовые операции Розничная торговля Бесплатно (free) Работа с интерфейсом

Простой пример, как с помощью программного изменения шрифтов элементов формы достичь наилучшего результата отображения на примере формы РМК.

04.10.2018    10771    asdfgcom    56       

Авансы, кредиты и предоплаты. Примеры чеков ФФД 1.05 24

Статья Бухгалтер Нет файла v8 УТ11 Розничная и сетевая торговля (FMCG) Россия БУ Розничная торговля Бесплатно (free) ККМ

В публикации рассмотрено, как должны выглядеть корректные чеки ФФД 1.05 при авансах, кредитах и предоплатах. Чеки получены с помощью демонстрационной базы 1С:Управление торговлей 11.4.5.54 (Платформа 8.3.11.3034).

30.07.2018    29902    vasilievil    27       

Отправка http запросов с Дайджест-аутентификацией из 1С на примере кассового аппарата MG N707TS 4

Статья Системный администратор Программист Нет файла v8 1cv8.cf Украина Бесплатно (free) ККМ

Возникала необходимость использовать кассовый аппарат MG N707TS под ubuntu, как известно, COM объекты не поддерживаются. На самом деле не все так сложно! Расписывать долго не буду, смотрите "Процедура КнопкаСформироватьНажатие" , может кому пригодится.

16.07.2018    4384    IgKR    8       

Чеки ККМ онлайн касс Атол на конфигурации КА 1.1 5

Статья Программист Нет файла v8 КА1 Россия Кассовые операции Бесплатно (free) ККМ

Онлайн касса печатает тип СНО УСН, хотя организация работает на ЕНВД.

13.07.2018    6992    dima_finne    6       

Распределение остатков по партиям прихода 5

Статья Программист Нет файла v8 1cv8.cf Россия УУ Оптовая торговля Розничная торговля Ценообразование, анализ цен Бесплатно (free) Практика программирования

Распределение свободных остатков номенклатуры по документам прихода по убыванию даты поступления товаров в РАУЗ.

21.06.2018    3969    maxvcb    0       

Учет и сверка Z-Отчетов ККМ в 1С 15

Статья Программист Нет файла v8 КА1 УПП1 Розничная и сетевая торговля (FMCG) Россия БУ Кассовые операции Бесплатно (free) ККМ

Думаю, все крупные компании при внедрении/эксплуатации 1С делают значительные изменения в ее конфигурации. Как бы вы ни пытались все бизнес процессы решить типовыми решениями от 1С, все равно наступает момент, когда приходится заняться конфигурированием. Я решил написать серию статей, где постараюсь описать решения, которые мне пришлось реализовывать в разных компаниях. Если разработчики 1С посчитают что-то интересным для внедрения в типовые решения, мы будем только рады. В текущей статье речь пойдет о кассовых z-отчетах в 1С.

03.06.2018    12794    dima_home    12       

Подключение онлайн кассы (ККМ) ATOL к УТ 10.3 в терминале. Личный опыт 20

Статья Системный администратор Программист Нет файла v8 БП2.0 УТ10 Windows Кассовые операции Бесплатно (free) ККМ

Использование Онлайн Кассы на Windows HOME c драйвером без цифровой подписи. Проброска портов для ККМ. Использование компьютера с кассой в качестве сервера для быстрой печати чеков через терминал без использования сквозных COM портов.

10.05.2018    21150    pridecom    26       

История развития 1С:Торговли, что изменилось в архитектуре учета торговых и складских операций за 15 лет 66

Статья no Нет файла v8 Оптовая торговля, дистрибуция, логистика Россия УУ Оптовая торговля Розничная торговля Учет ТМЦ Ценообразование, анализ цен Бесплатно (free) Пользователю системы

В данном обзоре я хочу рассмотреть историю развития учета торговых и складских операций в 1С с точки зрения архитектуры конфигурации. Еще раз повторюсь, именно конфигурации, структуры данных, а не технологических возможностей платформы. Т.е. речь не про управляемые формы и обычные формы, не про преимущество СУБД перед dbf в расшаренной папке, а про справочники, их реквизиты и код, который этим управляет. Конечно, совсем абстрагироваться от изменений платформы не удастся, но я постараюсь.

23.04.2018    16338    monkbest    57       

Автоматизация торговой деятельности как путь к лидерству на рынке. Часть 2 10

Статья Программист Бухгалтер Руководитель проекта Нет файла v8 ERP2 УТ11 КА2 Розничная и сетевая торговля (FMCG) Россия УУ Розничная торговля Бесплатно (free) Бухгалтерский учет

Продолжаем делиться опытом автоматизации торговой деятельности. В данной части статьи мы рассмотрим такие разделы учетной системы, как Прием заказов от клиентов и Складскую логистику. И постараемся показать, какие плюсы можно получить в результате автоматизации данных областей.

31.01.2018    9164    Апрель-С    6       

Интеграция 1С УТ 11.2 и Битрикс. Настройка выгрузки старой цены для интернет-магазина 8

Статья Программист Нет файла v8 УТ11 Россия УУ Розничная торговля Бесплатно (free) WEB

Настройки позволят вытащить информацию о старой цене из 1С и передать её в CMS Битрикс.

24.01.2018    7869    Consultant_1C    2       

Ошибка печати чека на ККМ Атол FPrint22. ПоследующаяОплата (Кредит) вместо Электронными. Розница 2 7

Статья Системный администратор Программист Нет файла v8 Розница Россия Кассовые операции Розничная торговля Бесплатно (free) Адаптация типовых решений ККМ

При печати чека на FPrint22 неожиданно выяснилось, что вместо Электронными (пробивали по платежной карте) в чеке вставало на вид оплат ПоследущаяОплата (Кредит).

22.01.2018    22955    ah7777777    15       

Использование драйвера Штрих-М для электронных весов Штрих Слим в 1С: Розница 2.2 3

Статья Системный администратор Программист Нет файла v8 Розница Windows Розничная торговля Бесплатно (free) Весы

Пост для тех, у кого возник вопрос о недоступности выбора драйвера Штрих-М для подключения электронных весов. Сам пытался отыскать простое решение на просторах интернета. Но даже решение на infostart требует использование обработок. Что, согласитесь, не так легко будет в местах, лишенных интернета, а вопрос надо решить по телефону.

12.12.2017    11500    kliakson    2       

Подключение весов "Масса-К" к 1С без драйверов и обработок 7

Статья Программист Нет файла v8 Розница Розничная и сетевая торговля (FMCG) Россия Розничная торговля Бесплатно (free) Весы

Для весов серии "Масса-К", имеющих интерфейс RS-232 для связи весов с ПК, возможна простая процедура подключения к 1С.

03.10.2017    13319    grafit    6       

Редактирование шаблона чека ККТ 71

Статья Системный администратор Программист Нет файла v8 УТ10 УТ11 Россия Кассовые операции Бесплатно (free) Фискальный регистратор

Добрый день. Думаю, волна вопросов по подключению онлайн-касс к 1С уже позади, достаточно просто полистать данный ресурс, поэтому можно переходить на новый уровень. С изменением ФР на ККТ изменился формат обмена между 1С и оборудованием и стало намного сложнее управлять формой чека. В этой статье я расскажу, какие методы изменения формы чека я нашел и попробовал, данная статья относится к ККТ фирмы АТОЛ, т.к. на остальных я не тестировал.

01.10.2017    61266    tjurikov_ivan    38       

Подключение ККТ (Торгового оборудования) в разрезе Пользователя или Клиента RDP 30

Статья Программист Нет файла v8 1cv8.cf Кассовые операции Бесплатно (free) ККМ

Старые конфигурации (Комплексная автоматизаци 1.1, УТ 10.3...) не поддерживают разрез пользователей или клиентов RDP при подключение кассового оборудования. Решил немного освежить идею статьи https://infostart.ru/public/197612/ и комментарии Сергея Муравьёва и Сергея Капустина собрав воедино. В этой статье-заметке вы узнаете, как с минимальными доработками изменить видимость ККТ в разрезе пользователей или терминальных сессий по RDP даже с вводом новых документов по работе с ККТ.

28.09.2017    20196    rpgshnik    24       

Комплексное решение для малого бизнеса: 1С:УНФ + онлайн-касса "ШТРИХ-МPAY-Ф" 4

Статья Системный администратор Программист Нет файла v8 Россия Кассовые операции Бесплатно (free) ККМ

Фирма "1С" представляет новый программно-аппаратный комплекс для интернет-магазинов, предпринимателей и компаний сферы торговли и услуг, предпочитающих облачные решения, а также для тех, кто торгует алкоголем и кому в связи с этим необходимо обеспечить поддержку ЕГАИС.

29.08.2017    13729    user818734    5       

Ошибка интерфейса ЭКЛЗ/ФН1 или как правильно подключать фискальные регистраторы АТОЛ без ФН/ЕНВД 11

Статья Системный администратор Нет файла v8 Россия Windows Кассовые операции Бесплатно (free) Фискальный регистратор

В статье описывается решение проблем с подключением фискальных регистраторов АТОЛ без ФН/ЕНВД к 1С 8. Устранение ошибки, возникающей при попытке пробить чек: "Чек не напечатан на устройстве для печати чеков. Ошибка интерфейса ЭКЛЗ/ФН1".

12.08.2017    34385    Stan    11       

Подключение прайс-чекера ЗНАЙТ Z-Info к 1С в режиме Online 3

Статья Системный администратор Нет файла v8 УТ11 Розничная и сетевая торговля (FMCG) Россия Розничная торговля Бесплатно (free) Сканер штрих-кода

В статье рассматриваются особенности работы с прайс-чекером ЗНАЙТ Z-Info в типовой конфигурации "1С: Управление торговлей" редакция 11.1.2.18 (платформа 1С 8.2.19.80), когда база данных 1С хранится в СУБД Microsoft SQL Server, куда напрямую и подключается прайс-чекер для запроса информации.

06.07.2017    9549    user772738    0